FILENAME goptions URL "http://192.38.117.59/~linearpredictors/datafiles/goptions.sas";
%include goptions;

FILENAME url URL "http://192.38.117.59/~linearpredictors/datafiles/readPbc3.sas";
%include url;

DATA pbc3; SET pbc3;
    logbili=log(bili);
    bili0=(biligroup=0);
    bili1=(biligroup=1);
    bili2=(biligroup=2);
    bili3=(biligroup=3);
    bili4=(biligroup=4);
RUN;

PROC PHREG DATA=pbc3;
    MODEL followup*status(0)=bili1 bili2 bili3 bili4;
    OUTPUT OUT=estimates XBETA=loghazardratio/ ORDER=DATA;
RUN;

DATA pbc3;
    MERGE pbc3 estimates (KEEP=loghazardratio);
RUN;    

/* The average log(bilirubin) values in quintile groups
   are computed and merged with the data set */ 

PROC MEANS DATA=pbc3 MEAN NWAY;
    CLASS biligroup;
    VAR logbili;
    OUTPUT OUT=means MEAN = logbiliquintilemean;
RUN;

PROC SORT DATA=pbc3;
    BY biligroup;
RUN;

DATA pbc3;
    MERGE pbc3 means;
    BY biligroup;
RUN;

PROC GPLOT;
    PLOT loghazardratio*logbiliquintilemean/HAXIS=axis1 VAXIS=axis2;
    axis1 MINOR=NONE LABEL=('log(bilirubin)');
    axis2 MINOR=NONE LABEL=(A=90 R=0 'log(hazard ratio)');    
    SYMBOL1 V=CIRCLE I=NONE;
RUN;