FILENAME goptions URL "http://192.38.117.59/~linearpredictors/datafiles/goptions.sas";
%include goptions;

FILENAME url URL "http://192.38.117.59/~linearpredictors/datafiles/readFattyacids.sas";
%include url;

DATA fattyacids;
SET fattyacids;

logabsorption=log10(absorption);
RUN;

/****************************************************************
    In Table 3.2.3, 3.2.6, 3.2.7 and 3.2.7,
    Mixed Butter and Butter have been interchanged
    ***********************************************************/

title1 'NOTE: In Table 3.2.8, the second comparison concerns Butter, not Mixed Butter';
title2 'See note in program';

ods output estimates=effects1;

title3 'Necessary analyses, see results on later pages';
PROC GLM DATA=fattyacids; WHERE hours=8;
    CLASS product;
    MODEL logabsorption = product / CLPARM ALPHA=0.0125;
    ESTIMATE 'Cream vs. Cream Cheese' product 0 1 -1 0 0;
    ESTIMATE 'Butter vs. Cream Cheese' product 1 0 -1 0 0;
RUN;
QUIT;

ods output estimates=effects2;
ods output CLDiffs=effects3;

PROC GLM DATA=fattyacids; WHERE hours=8;
    CLASS product;
    MODEL logabsorption = product / CLPARM;
    ESTIMATE 'Cream vs. Cream Cheese' product 0 1 -1 0 0;
    ESTIMATE 'Butter vs. Cream Cheese' product 1 0 -1 0 0;
    MEANS product / DUNNETT("Cream Cheese");
    MEANS product / BON;
    MEANS product / TUKEY;
RUN;

DATA effects1;
SET effects1;

estimated_ratio=10**(Estimate);
ratio_lower=10**LowerCL;
ratio_upper=10**UpperCL;
RUN;

title3 'Bonferroni/Sidak, comparison to Cream Cheese only';
PROC PRINT DATA=effects1;
VAR Parameter estimated_ratio ratio_lower ratio_upper;
RUN;

DATA effects2;
SET effects2;

estimated_ratio=10**(Estimate);
ratio_lower=10**LowerCL;
ratio_upper=10**UpperCL;
RUN;

title3 'Ordinary single comparisons';
PROC PRINT DATA=effects2;
VAR Parameter estimated_ratio ratio_lower ratio_upper;
RUN;

DATA effects3;
SET effects3;

estimated_ratio=10**(Difference);
ratio_lower=10**LowerCL;
ratio_upper=10**UpperCL;
control=substr(Comparison,16,12);
active=substr(Comparison,1,12);
RUN;

title3 'Dunnett, Bonferroni and Tukey corrections';
PROC PRINT DATA=effects3; where active in ('Cream       ','Butter      ') and control='Cream Cheese';
VAR Method Comparison estimated_ratio ratio_lower ratio_upper;
RUN;