FILENAME goptions URL "http://192.38.117.59/~linearpredictors/datafiles/goptions.sas";
%include goptions;

FILENAME url URL "http://192.38.117.59/~linearpredictors/datafiles/readVitaminD.sas";
%include url;

/*
All women
*/ 

DATA women;
	SET vitamind (WHERE = (category=2));

        logvitd=log10(vitd);
        logvitdintake=log10(vitdintake);
RUN;

ods output estimates=effects;

title 'Estimates from Final model';
PROC GLM DATA=women;
    CLASS country;
    MODEL logvitd = bmi country country*logvitdintake / clparm;
    format country countryf.;
ESTIMATE 'Effect of log(intake), DK' country*logvitdintake 1 0 0 0;
ESTIMATE 'Effect of log(intake), SF' country*logvitdintake 0 1 0 0;
ESTIMATE 'Effect of log(intake), EI' country*logvitdintake 0 0 1 0;
ESTIMATE 'Effect of log(intake), PL' country*logvitdintake 0 0 0 1;
run;

DATA effects;
SET effects;

effect_of_doubling=2**(Estimate);
doubling_lower=2**LowerCL;
doubling_upper=2**UpperCL;
RUN;

PROC PRINT DATA=effects;
VAR Parameter Estimate LowerCL UpperCL;
RUN;

PROC PRINT DATA=effects;
VAR Parameter effect_of_doubling doubling_lower doubling_upper;
RUN;